**Supplementary Material for:**

E. L. Hamaker, T. Asparouhov, A. Brose, F. Schmiedek, and B. Muthén: “At the frontiers of modeling intensive

longitudinal data: Dynamic structural equation models for the affective measurements from the COGITO

study.” *Multivariate Behavioral Research.*

**Mplus code for Model 1: Multilevel bivariate VAR(1) model with random means and random lagged parameters**

TITLE: Cogito data

DATA: file is CogitoOlder.dat;

VARIABLE:

NAMES = id sessdate na1 na2 na3 na4 na5 na6 na7 na8 na9 na10

 pa1 pa2 pa3 pa4 pa5 pa6 pa7 pa8 pa9 pa10 sessionNr

 age\_pre sex CESDpre CESDpost dayNA dayPA older;

CLUSTER = id;

USEVAR = dayPA dayNA;

LAGGED = dayPA(1) dayNA(1);

TINTERVAL = sessdate(1);

MISSING = all(-999);

ANALYSIS: TYPE IS TWOLEVEL RANDOM;

 ESTIMATOR = BAYES;

 PROC = 2; BITER = (5000);

 BSEED = 5699; THIN = 10;

MODEL:

 %WITHIN%

 p\_pp | dayPA ON dayPA&1; ! Random slope for PA\_t regressed on PA\_t-1 (autoregression)

 p\_pn | dayPA ON dayNA&1; ! Random slope for PA\_t regressed on NA\_t-1 (cross-lagged)

 p\_np | dayNA ON dayPA&1; ! Random slope for NA\_t regressed on PA\_t-1 (cross-lagged)

 p\_nn | dayNA ON dayNA&1; ! Random slope for NA\_t regressed on NA\_t-1 (autoregression)

 %BETWEEN%

 p\_pp-p\_nn dayPA dayNA WITH p\_pn-p\_nn dayPA dayNA; ! Correlations between all 6 random effects

OUTPUT: TECH1 TECH8 STDYX;

PLOT: TYPE = PLOT3; FACTOR =ALL;

**Mplus code for Model 2: Multilevel bivariate VAR(1) model with random means, random lagged parameters, and random innovation variances and covariance**

TITLE: Cogito data

DATA: file is CogitoOlder.dat;

VARIABLE:

NAMES = id sessdate na1 na2 na3 na4 na5 na6 na7 na8 na9 na10

 pa1 pa2 pa3 pa4 pa5 pa6 pa7 pa8 pa9 pa10 sessionNr

 age\_pre sex CESDpre CESDpost dayNA dayPA older;

CLUSTER = id;

USEVAR = dayPA dayNA;

LAGGED = dayPA(1) dayNA(1);

TINTERVAL = sessdate(1);

MISSING = all(-999);

ANALYSIS: TYPE IS TWOLEVEL RANDOM;

 ESTIMATOR = BAYES;

 PROC = 2; BITER = (5000);

 BSEED = 5699; THIN = 10;

MODEL:

 %WITHIN%

 p\_pp | dayPA ON dayPA&1; ! Random slope for PA\_t regressed on PA\_t-1 (autoregression)

 p\_pn | dayPA ON dayNA&1; ! Random slope for PA\_t regressed on NA\_t-1 (cross-lagged)

 p\_np | dayNA ON dayPA&1; ! Random slope for NA\_t regressed on PA\_t-1 (cross-lagged)

 p\_nn | dayNA ON dayNA&1; ! Random slope for NA\_t regressed on NA\_t-1 (autoregression)

 eta BY dayPA@1 dayNA@-1; ! Latent variable representing negative covariance between innovations of PA and NA

 logpsi | eta; ! Random negative covariance

 logpi\_PA | dayPA; ! Random unique innovation variance for PA

 logpi\_NA | dayNA; ! Random unique innovation variance for NA

 %BETWEEN%

 p\_pp-p\_nn logpi\_PA logpi\_NA logpsi dayPA dayNA WITH

 p\_pn-p\_nn logpi\_PA logpi\_NA logpsi dayPA dayNA; ! Allow all 9 random effects to covary

OUTPUT: TECH1 TECH8 STDYX STAND(CLUSTER) FSCOMPARISON;

PLOT: TYPE = PLOT3; FACTOR =ALL;

**Mplus code for Model 3: Multilevel bivariate VAR(1) model with random means, random lagged parameters, and random innovation variances and covariance, and between-person level predictor and outcome**

TITLE: Cogito data

DATA: file is CogitoOlder.dat;

VARIABLE:

NAMES = id sessdate na1 na2 na3 na4 na5 na6 na7 na8 na9 na10

 pa1 pa2 pa3 pa4 pa5 pa6 pa7 pa8 pa9 pa10 sessionNr

 age\_pre sex CESDpre CESDpost dayNA dayPA older;

CLUSTER = id;

USEVAR = dayPA dayNA CESDpre CESDpost;

BETWEEN = CESDpre CESDpost;

LAGGED = dayPA(1) dayNA(1);

TINTERVAL = sessdate(1);

MISSING = all(-999);

DEFINE: CENTER CESDpre CESDpost (GRANDMEAN);

ANALYSIS: TYPE IS TWOLEVEL RANDOM;

 ESTIMATOR = BAYES;

 PROC = 2; BITER = (5000);

 BSEED = 5682; THIN = 10;

MODEL:

 %WITHIN%

 p\_pp | dayPA ON dayPA&1; ! Random slope for PA\_t regressed on PA\_t-1 (autoregression)

 p\_pn | dayPA ON dayNA&1; ! Random slope for PA\_t regressed on NA\_t-1 (cross-lagged)

 p\_np | dayNA ON dayPA&1; ! Random slope for NA\_t regressed on PA\_t-1 (cross-lagged)

 p\_nn | dayNA ON dayNA&1; ! Random slope for NA\_t regressed on NA\_t-1 (autoregression)

eta BY dayPA@1 dayNA@-1; ! Latent variable representing negative covariance between innovations of PA and NA

 logpsi | eta; ! Random negative covariance

 logpi\_PA | dayPA; ! Random unique innovation variance for PA

 logpi\_NA | dayNA; ! Random unique innovation variance for NA

 %BETWEEN%

 p\_pp-p\_nn dayPA dayNA ON CESDpre (a1-a6); ! Regress all 4 random slopes and 2 random means on between level predictor

 logpi\_PA logpi\_NA logpsi ON CESDpre (a7-a9); ! Regress all 3 random variances on between level predictor

 CESDpost ON p\_pp-p\_nn dayPA dayNA logpi\_PA logpi\_NA logpsi CESDpre (b1-b10); ! Regress between level outcome on all 9 random

 ! effects and the between level predictor

 MODEL CONSTRAINT:

 new (ab\_p\_pp); ab\_p\_pp=a1\*b1; ! Compute indirect effect through autoregression of PA

 new (ab\_p\_pn); ab\_p\_pn=a2\*b2; ! Compute indirect effect through cross-lagged regression from NA to PA

 new (ab\_p\_np); ab\_p\_np=a3\*b3; ! Compute indirect effect through cross-lagged regression from PA to NA

 new (ab\_p\_nn); ab\_p\_nn=a4\*b4; ! Compute indirect effect through autoregression of NA

 new (ab\_dayPA); ab\_dayPA=a5\*b5; ! Compute indirect effect through mean of PA

 new (ab\_dayNA); ab\_dayNA=a6\*b6; ! Compute indirect effect through mean of NA

 new (ab\_lvPA); ab\_lvPA=a7\*b7; ! Compute indirect effect through log of the unique innovation variance of PA

 new (ab\_lvNA); ab\_lvNA=a8\*b8; ! Compute indirect effect through log of the unique innovation variance of NA

 new (ab\_lCov); ab\_lCov=a9\*b9; ! Compute indirect effect through log of the negative innovation covariance of PA and NA

OUTPUT: TECH1 TECH8;

PLOT: TYPE = PLOT3; FACTOR =ALL;